<<back to skureal media art lab

LM3886 in LTspice nutzen

Thursday, 26 November 2009 17:02

There are no translations available.

Um eine Schaltung mit einem LM3886 mit LTspice zu simulieren sind einige Schritte nötig, die im folgenden erklärt werden sollen. - Modelldatei anlegen - Schaltsymbol erstellen - in Schaltung importieren

Es gibt verschiedene Modelle, exemplarisch wird temuk's modell verwendet:

Modelldatei lm3886.sub anlegen

.SUBCKT LM3886 posin negin out posrail negrail mute gndpin
* IN+ IN- OUT VCC VEE MUTE GND
* 
* LM3886 spice model by teemuk 21032007 ver.1b
Q1 posrail posin N004 0 NPN
I1 N004 negrail 0.25m
Q2 posrail negin N003 0 NPN
I2 N003 negrail 0.25m
Q3 N011 N003 N010 0 PNP
Q4 N011 N018 N012 0 NPN
R1 N012 negrail 2.2k
I3 N018 negrail 0.1m
Q5 N017 N018 N024 0 NPN
R2 N024 negrail 2.2k
Q6 posrail N011 N018 0 NPN
R3 N009 N010 1.1k
R4 N009 N023 1.1k
Q7 N017 N004 N023 0 PNP
Q8 N017 N013 N016 0 PNP
Q9 N011 N025 N019 0 PNP
R5 N015 N016 4.7k
R6 N015 N019 4.7k
R7 N013 gndpin 10k
D1 N025 gndpin D
D2 gndpin N025 D
R8 out N025 10k
C1 out N017 10p
I4 N026 negrail 1m
Q10 posrail N017 N026 0 NPN
Q11 N030 N026 N031 0 NPN
R9 N031 negrail 800
Q12 N009 N008 N014 0 PNP
Q13 N015 N022 N014 0 PNP
I5 posrail N014 1m
I6 N022 negrail 1m
D3 N021 N022 D
D4 N020 N021 D
R10 posrail N020 1k
D5 N007 N008 D
D6 N006 N007 D
R11 posrail N006 1k
Q14 N008 gndpin N005 0 NPN
R12 N005 N001 1k
D7 N002 mute D
D8 N001 N002 D
D9 N032 N031 D
R13 N034 negrail 150
Q15 out N032 N034 0 NPN
Q16 out N034 N036 0 NPN
R14 N036 negrail 0.45
Q17 N032 N030 out 0 PNP
D10 N029 N030 D
D11 N028 N029 D
D12 N027 N028 D
R15 N033 out 150
Q18 posrail N027 N033 0 NPN
Q19 posrail N033 N035 0 NPN
R16 N035 out 0.45
I7 posrail N027 2.5m
.model D D
.model NPN NPN
.model PNP PNP
.end lm3886

Diese Daten werden in einer datei lm3886.sub gespeichert und im Verzeichnis

"c:\Programme\LTC\LTspiceIV\lib\sub\" abgelegt.

Schaltsymbol für den LM3886 erstellen

Als nächstes erstellt man mit LTspice ein Modell mit 7 Pins, in folgender Reihenfolge:

1:IN+ 2:IN- 3:OUT 4:VCC 5:VEE 6:MUTE 7:GND

Benutzung des Modells in der Schaltung:

Im LTspice Editor wird das Schaltsymbol für den LM3886 wird einfach über "edit / add component" ( "F2" ) hinzugefügt.

Ein Rechtsklick auf das Schaltsymbol öffnet den Editor für die Attribute. Der prefix wird auf "X" gesetzt.

Dies ist nötig zur Benutzung einer externen Modelldatei. Im Feld "value" wird nun der Wert "lm3886" eingetragen, was LTspice nach einer "lm3886.sub" suchen lässt.

Damit diese erfolgreich wird, fügt man über "edit / SPICE Directive " ( "S" )ein Direktive hinzu mit folgendem Inhalt: ".lib filename.sub" (oder je nachdem wie die .sub benannt wurde). Falls diese Datei nicht im Verzeichnis "LIB\SUB" liegt, muss hier der komplette Pfad angegeben werden, also am besten gleich dort ablegen.

lm3886.asy